! 分子の読み込み
! ファイル名を""で囲みます．
! LOAD "c:\pdb files\sample.pdb"　のように書きます．
! $BIOBOXでBioBoxがインストールされているフォルダを指定できます．

LOAD "$BIOBOX\sample\sample01.pdb"


! 経過時間指定（数値 x 100ms）

# 1

! ズーム（120％）

ZOOM 120

! レンダリング（全ての原子をStickで表示します）

RENDER * Stick Normal Normal

# 5

! レンダリング（一つ目の分子をBall&Stickで表示します）

RENDER 1 BallandStick Normal Normal

# 5

! レンダリング（二つ目の分子をSpacefillで表示します）

RENDER 2 Spacefill Normal Normal

# 5

! レンダリング（全ての原子をDotで表示します）

RENDER * Dot Normal Normal

# 5

! レンダリング（全ての原子をWireframeで表示します）

RENDER * Wireframe Normal Normal

# 5


! ナビゲーション
! ウィンドウに表示したい文字列を""で囲みます．
! 日本語も表示することができます．
NAVI "Loop　Start..."


! ループ開始（５回）
! 数値に 0 を指定すると無限ループになります．

LOOP 5

# 10


! 自動回転モード（Ｙ軸回転）

ROTATION ON 0 +5


! レンダリング（全てのP原子をSpacefillで表示します）

RENDER *:*:P Spacefill Biggest Smallest


! 色指定（残基別の色に表示を変更します）

COLOR * Group -


! ラベル（全分子のP原子，S原子に残基名を表示します）

LABEL *:*:P Group -
LABEL *:*:S Group -


! リボン（消去）

RIBBON * OFF - -


# 10


! 自動回転モード（Ｘ軸回転）

ROTATION ON 5 0


! レンダリング（全ての分子をBallandStickで表示します）

RENDER * BallandStick Small Normal


! 色指定（原子別の色に表示を変更します）

COLOR * Atom -


! ラベル（消去）

LABEL * OFF -


! リボン（全ての分子にHelixリボンを表示します）

RIBBON * Helix Smallest Red
RIBBON 1 Wireframe Biggest White


! ループ繰り返し
! 直前に指定したLOOPの位置に処理を移します．

LEND


NAVI "Loop　End."


! 自動回転モード解除

ROTATION OFF 0 0 0


! ムービーはここまでです．


! スクリプト書式

! LOAD	    ["分子ファイル名"]
! LOOP	    [ループ回数]	（０を指定すると無限ループになる）
! LEND	    (ループ終端)
! #	    [経過時間]		（およそ、数値x100ms）
! MOVE	    [対象分子]  [ON/OFF]
! SEEN	    [対象分子]  [ON/OFF]
! RENDER    [対象分子]  [RENDER]  [STICK SIZE]  [BALL SIZE]
! COLOR	    [対象分子]  [COLOR]  [COLOR]
! LABEL	    [対象分子]  [LABEL]  [COLOR]
! RIBBON    [対象分子]  [RIBBON]  [RIBBON SIZE]  [COLOR]
! TRACE	    [対象分子]  [ON/OFF]
! STEREO    [ON/OFF]
! ROTATION  [ON/OFF]  [X ROTATION]  [Y ROTATION]
! NAVI	    ["出力文字列"]
! ZOOM	    [拡大率]		（70 - 250%）
! !	コメントアウト（１文字目のみ有効）


! 対象分子書式

! *		全分子  
! 1		番号１の分子  
! 1-3,5		番号１〜３の分子と番号５の分子  
! 1:GUA_2	番号１の分子のGUA_2残基  
! *:GUA		全てのGUA残基  
! *:2		全ての残基番号２の残基  
! *:3-5,7-9	残基番号３〜５，７〜９の残基  
! 2:ADE_3:C3'	番号２の分子のADE_3のC3'原子  
! *:*:P		全てのP原子  
! *:1:C*	残基番号１の全てのC原子  
! *:*:N*,O*	全てのN原子とO原子  
! *:3-20:P	残基番号３から20までのP原子  

! 注意！

! *:H2'		これは間違いです．全てのH2'原子を指定する場合は *:*:H2' としてください．

! 残基名，残基番号，原子名はBioBoxのPickAtomで表示されるものと同じです．
! 1:GUA_2 を 1:G_2 と書いても認識されません．

! ループ内でLOADを実行しないようにしてください．
! 例えば、
! LOOP 0
! LOAD "test.pdb"
! LEND
! これを実行すると無限にtest.pdbを読み込みつづけることになります．
! LOAD はスクリプトの最初にまとめておくようにしてください．


! オプション

! RENDER
! [RENDER]	Wireframe Stick BallandStick Spacefill Dot OFF
! [STICK SIZE]	Normal Big Bigger Biggest Smallest Smaller Small
! [BALL SIZE]	Normal Big Bigger Biggest Smallest Smaller Small

! COLOR!
! [COLOR]	Group Molecule Atom
! [COLOR]	White Red Green Blue Yellow Purple SkyBlue LightGreen Pink Orange Gley

! LABEL
! [LABEL]	OFF Atom Group Molecule
! [COLOR]	White Red Green Blue Yellow Purple SkyBlue LightGreen Pink Orange Gley

! RIBBON
! [RIBBON]	OFF Line Wireframe Helix
! [RIBBON SIZE]	Normal Big Bigger Biggest Smallest Smaller Small
! [COLOR]	Molecule White Red Green Blue Yellow Purple SkyBlue LightGreen Pink Orange Gley